Draft: Build tests when 'make test'

It is a bit annoying that we have to configure the project with -DBUILD_TESTING=OFF in ICON and, therefore, cannot run the tests (make check for ICON is translated to make test for fortran-support, which essentially does nothing). The reason why we have to disable the test is that we don't want ICON users to fetch GTest and FortUTF every time the build the model (most of the users do not need to run the tests). We also don't want them to have to build what they don't need (i.e. the test executables). Additionally, building executables is sometimes more problematic on some platforms than building only the static libraries, which are needed for ICON. In contrast to Autoconf, building the test executables with make all (or just make) is the standard approach in CMake.

This is my attempt to make the building of the test executables and the fetching of the required libraries part of the test target. This way, GTest is fetched and the tests are built only when the user runs make test. Unfortunately, it is much more tricky to do that FortUTF because we need to run fortutf.cmake to declare the test executable. Therefore, I temporarily disabled the Fortran tests in the source branch of this MR to demonstrate the idea. I will need to solve this problem and probably polish the scripting for the GTest-based tests if we decide to go this way.

I am not sure yet if it's worth it at all but I did some experimenting and decided to show the results.

test/c/CMakeLists.txt

@@ -2,29 +2,40 @@ enable_language(CXX)
 
 find_package(GTest 1.13)
 if(NOT GTest_FOUND)
-  message(CHECK_START "Fetching external GTest")
-  if ("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.24")
-    cmake_policy(SET CMP0135 NEW)
-  endif()
-  include(FetchContent)
-  FetchContent_Declare(googletest
+  include(ExternalProject)
+  ExternalProject_Add(googletest
     URL https://github.com/google/googletest/archive/refs/tags/v1.13.0.tar.gz
     URL_HASH MD5=95b29f0038ec84a611df951d74d99897
+    PREFIX "${CMAKE_BINARY_DIR}/_deps/googletest"
+    SOURCE_DIR "${CMAKE_BINARY_DIR}/_deps/googletest-src"
+    BINARY_DIR "${CMAKE_BINARY_DIR}/_deps/googletest-build"
+    CMAKE_ARGS
+      -DBUILD_GMOCK:BOOL=OFF
+      -DBUILD_SHARED_LIBS:BOOL=${BUILD_SHARED_LIBS}
+      -Dgtest_disable_pthreads:BOOL=ON
+    STEP_TARGETS build
+    EXCLUDE_FROM_ALL TRUE
   )
-  set(INSTALL_GTEST OFF CACHE BOOL "Disable installation of googletest")
-  set(BUILD_GMOCK OFF CACHE BOOL "Do not build the googlemock subproject")
-  FetchContent_MakeAvailable(googletest)
-  # GTest puts its build artifacts to ${CMAKE_BINARY_DIR} instead of
-  # ${CMAKE_CURRENT_BINARY_DIR}. Therefore, we have to make it behave:
-  set_target_properties(gtest_main gtest
-    PROPERTIES
-      RUNTIME_OUTPUT_DIRECTORY "${googletest_BINARY_DIR}/bin"
-      LIBRARY_OUTPUT_DIRECTORY "${googletest_BINARY_DIR}/lib"
-      ARCHIVE_OUTPUT_DIRECTORY "${googletest_BINARY_DIR}/lib"
-      PDB_OUTPUT_DIRECTORY "${googletest_BINARY_DIR}/bin"
-      COMPILE_PDB_OUTPUT_DIRECTORY "${googletest_BINARY_DIR}/lib"
+  add_library(googletest-external INTERFACE)
+  add_dependencies(googletest-external googletest-build)
+  target_compile_features(googletest-external
+    INTERFACE
+      cxx_std_14
   )
-  message(CHECK_PASS "done")
+  target_include_directories(googletest-external
+    INTERFACE
+      "${CMAKE_BINARY_DIR}/_deps/googletest-src/googletest/include"
+  )
+  target_link_directories(googletest-external
+    INTERFACE
+      "${CMAKE_BINARY_DIR}/_deps/googletest-build/lib"
+  )
+  target_link_libraries(googletest-external
+    INTERFACE
+      gtest_main
+      gtest
+  )
+  add_library(GTest::gtest_main ALIAS googletest-external)
 endif()
 
 include("${PROJECT_SOURCE_DIR}/cmake/gtest_helper.cmake")