uniform_partition.f90

! uniform_partition.f90 --- compute uniform partitions
!
! Copyright  (C)  2010  Thomas Jahns <jahns@dkrz.de>
!
! Version: 1.0
! Keywords: uniform distribution partition
! Author: Thomas Jahns <jahns@dkrz.de>
! Maintainer: Thomas Jahns <jahns@dkrz.de>
! URL: https://www.dkrz.de/redmine/projects/show/scales-ppm
!
! Redistribution and use in source and binary forms, with or without
! modification, are  permitted provided that the following conditions are
! met:
!
! Redistributions of source code must retain the above copyright notice,
! this list of conditions and the following disclaimer.
!
! Redistributions in binary form must reproduce the above copyright
! notice, this list of conditions and the following disclaimer in the
! documentation and/or other materials provided with the distribution.
!
! Neither the name of the DKRZ GmbH nor the names of its contributors
! may be used to endorse or promote products derived from this software
! without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
! IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
! TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
! PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER
! OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
! EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
! PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
! PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
! LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
! NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
! SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
!
! Commentary:
!
!
!
! Code:
!
MODULE uniform_partition
  USE ppm_base, ONLY: abort_ppm
  USE ppm_extents, ONLY: extent, extent_size, extent_start
  USE mo_kind, ONLY: i8
  IMPLICIT NONE
  PRIVATE
  PUBLIC :: uniform_partition_1d, uniform_decomposition_1d, &
       uniform_decomposition_2d
CONTAINS
  !> compute start integer of uniform interval partition
  PURE FUNCTION uniform_partition_1d_start(set_interval, nparts, part_idx, &
       symmetric) RESULT(start)
    INTEGER, INTENT(in) :: nparts
    TYPE(extent), INTENT(in) :: set_interval
    INTEGER, INTENT(in) :: part_idx
    LOGICAL, INTENT(in) :: symmetric
    INTEGER :: start, part_offset, sym_part_idx

    IF (symmetric) THEN
      sym_part_idx = MERGE(part_idx - 1, nparts - part_idx + 1, &
           part_idx - 1 < nparts/2)
      part_offset = INT((INT(extent_size(set_interval), i8)/2_i8 &
           &          * INT(sym_part_idx, i8)) / (INT(nparts, i8)/2_i8))
      IF (part_idx - 1 >= nparts/2) THEN
        part_offset = extent_size(set_interval) - part_offset + 1
      END IF
    ELSE
      part_offset = INT((INT(extent_size(set_interval), i8) &
           &             * INT(part_idx - 1, i8)) / INT(nparts, i8))
    END IF
    start = extent_start(set_interval) + part_offset
  END FUNCTION uniform_partition_1d_start

  !> compute nth partition of integer set interval divided into
  !> roughly same sized sub-intervals forming a uniform partitioning
  PURE FUNCTION uniform_partition_1d(set_interval, nparts, part_idx, &
       symmetric) RESULT(interval)
    INTEGER, INTENT(in) :: nparts
    TYPE(extent), INTENT(in) :: set_interval
    INTEGER, INTENT(in) :: part_idx
    LOGICAL, OPTIONAL, INTENT(in) :: symmetric

    TYPE(extent) :: interval
    LOGICAL :: symmetric_pass
    INTEGER :: start_part, start_next_part
    IF (PRESENT(symmetric)) THEN
      symmetric_pass = symmetric
    ELSE
      symmetric_pass = .FALSE.
    END IF
    start_part = uniform_partition_1d_start(set_interval, nparts, part_idx, &
         symmetric_pass)
    start_next_part = uniform_partition_1d_start(set_interval, nparts, &
         part_idx + 1, symmetric_pass)
    interval = extent(start_part, start_next_part - start_part)
  END FUNCTION uniform_partition_1d
  !> divide integer set interval into evenly sized sub-intervals
  !> forming a partition
  !>
  SUBROUTINE uniform_decomposition_1d(set_interval, nparts, &
       part_idx, partition, all_partitions, symmetric)
    INTEGER, INTENT(in) :: nparts
    TYPE(extent), INTENT(in) :: set_interval
    INTEGER, OPTIONAL, INTENT(in) :: part_idx
    TYPE(extent), OPTIONAL, INTENT(out) :: partition
    TYPE(extent), OPTIONAL, INTENT(out) :: all_partitions(nparts)
    LOGICAL, OPTIONAL, INTENT(in) :: symmetric

    INTEGER :: i
    CHARACTER(len=240) :: msg
    IF (PRESENT(part_idx) .AND. .NOT. PRESENT(partition)) THEN
      msg = 'partition description requested without &
           & destination specifier partition'
      CALL abort_ppm(msg, __FILE__, __LINE__)
    END IF

    IF (.NOT. PRESENT(part_idx) .AND. PRESENT(partition)) THEN
      msg = 'partition description requested without &
           & specified partition id part_idx'
      CALL abort_ppm(msg, __FILE__, __LINE__)
    END IF

    IF (PRESENT(all_partitions)) THEN
      DO i = 1, nparts
        all_partitions(i) = uniform_partition_1d(set_interval, nparts, i, &
             symmetric=symmetric)
      END DO
      IF (PRESENT(part_idx)) partition = all_partitions(part_idx)
    ELSEIF (PRESENT(part_idx)) THEN
      partition = uniform_partition_1d(set_interval, nparts, part_idx, &
           symmetric=symmetric)
    END IF
  END SUBROUTINE uniform_decomposition_1d


  SUBROUTINE uniform_decomposition_2d(set_interval_x, set_interval_y, &
       nparts_x, nparts_y, part_idx_x, part_idx_y, partition, &
       all_partitions_x, all_partitions_y, symmetric)
    TYPE(extent), INTENT(in) :: set_interval_x, set_interval_y
    INTEGER, INTENT(in) :: nparts_x, nparts_y
    INTEGER, OPTIONAL, INTENT(in) :: part_idx_x, part_idx_y
    TYPE(extent), OPTIONAL, INTENT(out) :: partition(2)
    TYPE(extent), OPTIONAL, INTENT(out) :: &
         all_partitions_x(nparts_x), all_partitions_y(nparts_y)
    LOGICAL, OPTIONAL, INTENT(in) :: symmetric

    CHARACTER(len=240) :: msg

    IF ((PRESENT(part_idx_x) .OR. PRESENT(part_idx_y) .OR. PRESENT(partition))&
         .AND. .NOT. &
         (PRESENT(part_idx_x) .AND. PRESENT(part_idx_y) &
         .AND. PRESENT(partition))) THEN
      msg = "partition description request requires all of arguments &
           &part_idx_x, part_idx_y and partition"
      CALL abort_ppm(msg, __FILE__, __LINE__)
    END IF

    IF (PRESENT(all_partitions_x)) THEN
      CALL uniform_decomposition_1d(set_interval_x, nparts_x, &
           all_partitions=all_partitions_x, symmetric=symmetric)
      IF (PRESENT(partition)) partition(1) = all_partitions_x(part_idx_x)
    ELSEIF (PRESENT(partition)) THEN
      partition(1) = uniform_partition_1d(set_interval_x, nparts_x, part_idx_x)
    END IF

    IF (PRESENT(all_partitions_y)) THEN
      CALL uniform_decomposition_1d(set_interval_y, nparts_y, &
           all_partitions=all_partitions_y, symmetric=symmetric)
      IF (PRESENT(partition)) partition(2) = all_partitions_y(part_idx_y)
    ELSEIF (PRESENT(partition)) THEN
      partition(2) = uniform_partition_1d(set_interval_y, nparts_y, part_idx_y)
    END IF
  END SUBROUTINE uniform_decomposition_2d

END MODULE uniform_partition
!
! Local Variables:
! license-project-url: "https://www.dkrz.de/redmine/projects/show/scales-ppm"
! license-default: "bsd"
! End: